{$CLEO .cs}

{
GTA III Skin Changer
Controls
    [ Previous skin
    ] Next skin
    O Default skin
    P Show number of current skin
by DK'22
}

const
       player_act = $player_actor
       player_str = 1@
       index = 0@
       first_skin = 0
       last_skin = 0x52
       key_1 = 0xDB
       key_2 = 0xDD
       key_3 = 0x50
       key_4 = 0x4F
       _setModelIndex = 0x4C52A0
       flag = 2@
end

wait 250

:begin
while true
       wait 0
       if
           player.Defined(0)
       then
           if
               05EE: key_pressed key_3
           then       
               03F0: enable_text_draw 1
               01E3: text_1number_styled 'NUMBER' index 70 ms 3
           end    
           if
               05EE: key_pressed key_1
           then
               while 05EE: key_pressed key_1
                   if
                       not player.Defined(0)
                   then
                       goto @begin
                   end
                   wait 0
               end
               dec(index)
               if
                   index < first_skin    
               then
                   index = last_skin
               else if and
                       index >= 26
                       index <= 29
                   then
                       index = 25
                   end
               end
               flag = true
           else if
                   05EE: key_pressed key_2
               then
                   while 05EE: key_pressed key_2
                       if
                           not player.Defined(0)
                       then
                           goto @begin
                       end
                       wait 0
                   end
                   inc(index)
                   if
                       index > last_skin    
                   then
                       index = first_skin
                   else if and
                           index >= 26
                           index <= 29
                       then
                           index = 30
                       end
                   end
                   flag = true
               else if
                       05EE: key_pressed key_4
                   then
                       while 05EE: key_pressed key_4
                           if
                     not player.Defined(0)
                           then
                     goto @begin
                           end
                           wait 0
                       end                       
                       index = 0
                       flag = true
                   end                   
               end       
           end
           if
               flag == true
           then
               flag = false
               05E6: player_str = actor player_act struct
               if
                   not model.Available(index)
               then
                   model.Load(index)    
               end
               while not model.Available(index)
                   if
                       not player.Defined(0)
                   then
                       goto @begin
                   end
                   wait 0
               end
               05E3: call_method _setModelIndex struct player_str num_params 1 pop 0 index
           end
       end
end

{$CLEO .cs}

{
by DK22Pac, Vol-GTA
}

// Настройки
const
       shadowRadius = 2.5 // Радиус проекции
       shadowIntensity = 0xFF // Интенсивность проекции (0-255)
end

0000:
while true
       wait 0
       if
           not player.Defined(0)
       then
           continue
       end
       for 0@ = 0xC3E058 to 0xC3EF58 step 0x3C // перебор корон
           0A8E: 8@ = 0@ + 0x38 // Указатель на Entity(игровой субьект), к которому прицеплена корона
           0A8D: 1@ = read_memory 8@ size 4 virtual_protect false
           0A8D: 28@ = read_memory 0xB74494 size 4 virtual_protect 0 // Указатель на первый элемент в пуле транспорта
           0A8D: 28@ = read_memory 28@ size 4 virtual_protect 0    
           0A8D: 24@ = read_memory 0xB74494 size 4 virtual_protect false
           inc(24@, 8) // Указатель на максимальное кол-во элементов в пуле транспорта
           0A8D: 24@ = read_memory 24@ size 4 virtual_protect false    
           mul(24@, 0xA18)
           005A: 24@ += 28@           
           if and // Если данный Entity - автомобиль...
               002D: 1@ >= 28@
               8025: not 1@ > 24@
           then
               0AEB: 7@ = car_struct 1@ handle
               0A8E: 8@ = 0@ + 0x0
               0A8D: 21@ = read_memory 8@ size 4 virtual_protect false // X позиция короны
               inc(8@, 4)
               0A8D: 22@ = read_memory 8@ size 4 virtual_protect false // Y позиция короны
               inc(8@, 4)
               0A8D: 23@ = read_memory 8@ size 4 virtual_protect false // Z позиция короны
               0A8E: 8@ = 0@ + 0x2C
               0A8D: 4@ = read_memory 8@ size 1 virtual_protect false // Red    
               inc(8@)
               0A8D: 5@ = read_memory 8@ size 1 virtual_protect false // Green
               inc(8@)
               0A8D: 6@ = read_memory 8@ size 1 virtual_protect false // Blue    
               if
                   23@ > 0.2
               then
                   if
                       0137: car 7@ model == #COPBIKE // HPV1000
                   then
                       if and // Если это не корона передней фары
                           21@ < 0.2
                           21@ > -0.2
                       then
                           continue
                       end
                   end
                   04 07: store_coords_to 9@ 10@ 11@ from_car 7@ with_offset 21@ 22@ 23@ // Получаем мировые координаты                   
                   016F: add_shadow_type 3 rotation_factor 0.0 shadowRadius shadowIntensity RGB 4@ 5@ 6@ at 9@ 10@ 11@    
               end
           end
       end
end